360haven works best with JavaScript enabled
Counter Strike Global Offensive - Bind edit help - Page 3
Loading
Register
Page 3 of 3 FirstFirst 123
Results 17 to 20 of 20
  1. #17
    Shortbusninja

    Re: Counter Strike Global Offensive - Bind edit help

    It would be nice but there really isn't to much to do offline and from what I understand if you log online it checks for tampering and resets itself. That may just be my buddy (who hates mods) saying sh*t.

  2. #18
    saint-luciferr

    Re: Counter Strike Global Offensive - Bind edit help

    Anyone got further with this?

    Where the send commands are located?

    I have 2 Ps3 files zip0 and zip1, The large one contains a lot of information but cant extract from rar without memory error :(

    Any other ideas?

  3. #19
    xxsnuggl3sxx

    Re: Counter Strike Global Offensive - Bind edit help

    Quote Originally Posted by kostasishere View Post
    Here is a Quickbms script that i found and it can extract the zip0.360.zip in case anyone also want to use

    Code:
    # ZIP files example 0.4.2
    # more info: http://www.pkware.com/documents/casestudies/APPNOTE.TXT
    #   note that with some archives like those created by Stuff-it on MacOSX is
    #   not possible to use this script because they are wrongly built, practically
    #   they set the comp_size and uncomp_size fields of the "Local file header" at
    #   0 and they set them only in the relative "Central directory structure" which
    #   means that it's necesary to read this one first for extracting the files
    #   contained in the local header... senseless and stupid
    # script for QuickBMS http://quickbms.aluigi.org
    
    set ZIP_PASSWORD string ""  # put the password here (only ZipCrypto supported at the moment)
    
    set ZIP_SIGN short 0x0403
    goto 2
    get ZIP_SIGN short
    goto 0
    get zip_filesize asize
    for offset = 0 < zip_filesize
        #idstring "PK\x03\x04"
        get PK_sign short       # so it works also with modified ZIP files!
        get sign short
        if sign == ZIP_SIGN     # Local file header
            get ver             short
            get flag            short
            get method          short
            get modtime         short
            get moddate         short
            get crc             long
            get comp_size       long
            get uncomp_size     long
            get name_len        short
            get extra_len       short
            getdstring name     name_len
            getdstring extra    extra_len
            savepos offset
    
            # zip64
            if extra_len >= 20
                getvarchr extra_id extra 0 short
                if extra_id == 0x0001
                if comp_size == -1
                    getvarchr uncomp_size 4 longlong
                    getvarchr comp_size 12 longlong
                endif
                endif
            endif
    
            # possible lame tricks used by games
            if comp_size < 0
            if comp_size u> zip_filesize
                math comp_size ~= comp_size
                math uncomp_size ~= uncomp_size
            endif
            endif
            if name_len < 0
                math name_len ~= name_len
            endif
            if extra_len < 0
                math extra_len ~= extra_len
            endif
    
            if flag & 1
                if ZIP_PASSWORD == ""
                    print "the file is encrypted, you must set ZIP_PASSWORD in the script"
                    #cleanexit
                endif
                encryption zipcrypto ZIP_PASSWORD 1
            endif
            if method == 0
                Log name offset uncomp_size
            else
                if method == 8
                    ComType deflate
                elif method == 1
                    ComType unshrink
                elif method == 6
                    ComType explode
                elif method == 9
                    ComType deflate64
                elif method == 12
                    ComType bzip2
                elif method == 14
                    ComType lzmaefs
                elif method == 21
                    ComType XMemDecompress
                elif method == 64
                    ComType darksector
                elif method == 98
                    ComType ppmd
                elif method == 99
                    print "this script doesn't support AES encryption"
                    cleanexit
                else
                    print "unsupported compression method %method%"
                    cleanexit
                endif
                CLog name offset comp_size uncomp_size
            endif
            if flag & 1
                encryption "" ""
            endif
    
            math offset += comp_size
            goto offset
    
        elif sign == 0x0806     # Archive extra data record
            get extra_len       long
            getdstring extra    extra_len
    
        elif sign == 0x0201     # Central directory structure
            get ver_made        short
            get ver_need        short
            get flag            short
            get method          short
            get modtime         short
            get moddate         short
            get crc             long
            get comp_size       long
            get uncomp_size     long
            get name_len        short
            get extra_len       short
            get comm_len        short
            get disknum         short
            get int_attr        short
            get ext_attr        long
            get rel_offset      long
            getdstring name     name_len
            getdstring extra    extra_len
            getdstring comment  comm_len
    
        elif sign == 0x0505     # Digital Signature
            get sign_len        long
            getdstring sign     sign_len
    
        elif sign == 0x0606     # Zip64 end of central directory record
            get dir_record      longlong
            get ver_made        short
            get ver_need        short
            get num_disk        long
            get num_disk2       long
            get tot_entries     longlong
            get tot_entries2    longlong
            get central_size    longlong
            get central_offset  longlong
            print "Error: zip64 extensible data sector not implemented, contact me"
            cleanexit
    
        elif sign == 0x0706     # Zip64 end of central directory locator
            get start_central   long
            get end_central     longlong
            get disks           long
    
        elif sign == 0x0605     # End of central directory record
            get disk_num        short
            get disk_start      short
            get central_entries short
            get central_entries short
            get central_size    long
            get central_offset  long
            get comm_len        short
            getdstring comment  comm_len
    
        elif sign == 0x0807     # Data Descriptor
            get crc             long
            get comp_size       long
            get uncomp_size     long
    
        elif sign == 0x3030     # disk spanning
            # nothing?
    
        else
            print "\nError: unknown ZIP signature %sign% at offset %offset%\n       if the other files have been extracted correctly it's all ok"
            cleanexit
        endif
        savepos offset
    next
    it gives an error at the end of the extraction but it's ok and extract the cfg file,
    simple mod the cvars in the files you want (but the size must be the same or lower from the original so delete some empty space or text info)
    and to reimport the modded files use this method

    Code:
    export:Open quickbms.exe, select the script.bms, select the zip file, select folder to export
    
    reimport:  Delete first all the unmodded files from the extracted folder and keep only the modded files and folder/subfolder names, Open reimport, select script.bms,, select original zip file, select the modded folder with the custom/mods
    and again it gives a error at the end of reimport but the modded zip works fine and have the modded files inside so the game start fine.
    The only thing now is to figure out what is the correct files to mod because i try to bind a custom cvar in the config.360.cfg, controller.360.cfg and game360.cfg but it doesn't work.
    also ive noticed when droping whatever that file is that extracts from the zip0 there are values about half way down that talk about friction,gravity,recoil...not sure what they do yet but seems interesting to say the least.

  4. #20
    HEMI

    Re: Counter Strike Global Offensive - Bind edit help

    I hope someone help us here


 

 
Page 3 of 3 FirstFirst 123

Similar Threads

  1. [YouTube] Why Counter-Strike Is My Favorite Game Of All-Time
    By THUMBS in forum Youtube Famous
    Replies: 0
    Last Post: 06-02-2014, 05:16 PM
  2. [YouTube] Half-Life 3 'Being Worked On,' Says Counter-Strike Creator
    By THUMBS in forum Youtube Famous
    Replies: 0
    Last Post: 05-23-2014, 06:56 PM
  3. [Release] Counter-Strike: Go Awards Tool
    By godzcheater in forum Xbox 360 Modding Programs
    Replies: 11
    Last Post: 12-07-2013, 09:21 PM
  4. [X360] Counter Strike : GO RT Mods
    By iDev in forum Xbox 360 Modding Discussion
    Replies: 4
    Last Post: 10-08-2012, 08:57 PM

Visitors found this page by searching for:

Nobody landed on this page from a search engine, yet!

Tags for this Thread

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  

About 360haven

    360haven is an Forum Devoted To Game modding Fans from all over the world.

    An Awesome Community of Xbox 360 Gamers, Modders and Developers who Create & Share Tutorials, Applications, Gfx, Trainers and Gamesaves.

    A haven for the l33t.
    A scarce paradise for modders.

★★★★★¯\_(ツ)_/¯