Counter Strike Global Offensive - Bind edit help

[kostasishere]

Hi to all, is it possible to change the bind buttons with some customs like the L4D and L4D2? I tried with the tool for jtag/rgh edit ZipFix but it didn't work/extract correct the file zip0.360 and if i hex and change a button cvar the game gives a error and crash. The save for the Counter Strike i think is the GPD file but i didn't find what i need to change, here is the file if anyone want to take a look and thanks a lot for any help.

5841125A.rar | PutLocker

[Buddah]

i dont think there are binds in the gpd.... all of the stats are there though. i have them about 50% mapped out already

[kostasishere]

I also thought the same but the game doesn't allow you to choose the HDD storage and i have also check to change the buttons from the CS menu and they work fine after restart but again i am not sure. Thanks a lot for taking a look Buddah!

[Ravanofdarkness]

Would love to see if it's possible to reset the Trial Timer on the Trial Version.

[kostasishere]

Here is a Quickbms script that i found and it can extract the zip0.360.zip in case anyone also want to use

# ZIP files example 0.4.2
# more info: http://www.pkware.com/documents/casestudies/APPNOTE.TXT
#   note that with some archives like those created by Stuff-it on MacOSX is
#   not possible to use this script because they are wrongly built, practically
#   they set the comp_size and uncomp_size fields of the "Local file header" at
#   0 and they set them only in the relative "Central directory structure" which
#   means that it's necesary to read this one first for extracting the files
#   contained in the local header... senseless and stupid
# script for QuickBMS http://quickbms.aluigi.org

set ZIP_PASSWORD string ""  # put the password here (only ZipCrypto supported at the moment)

set ZIP_SIGN short 0x0403
goto 2
get ZIP_SIGN short
goto 0
get zip_filesize asize
for offset = 0 < zip_filesize
    #idstring "PK\x03\x04"
    get PK_sign short       # so it works also with modified ZIP files!
    get sign short
    if sign == ZIP_SIGN     # Local file header
        get ver             short
        get flag            short
        get method          short
        get modtime         short
        get moddate         short
        get crc             long
        get comp_size       long
        get uncomp_size     long
        get name_len        short
        get extra_len       short
        getdstring name     name_len
        getdstring extra    extra_len
        savepos offset

        # zip64
        if extra_len >= 20
            getvarchr extra_id extra 0 short
            if extra_id == 0x0001
            if comp_size == -1
                getvarchr uncomp_size 4 longlong
                getvarchr comp_size 12 longlong
            endif
            endif
        endif

        # possible lame tricks used by games
        if comp_size < 0
        if comp_size u> zip_filesize
            math comp_size ~= comp_size
            math uncomp_size ~= uncomp_size
        endif
        endif
        if name_len < 0
            math name_len ~= name_len
        endif
        if extra_len < 0
            math extra_len ~= extra_len
        endif

        if flag & 1
            if ZIP_PASSWORD == ""
                print "the file is encrypted, you must set ZIP_PASSWORD in the script"
                #cleanexit
            endif
            encryption zipcrypto ZIP_PASSWORD 1
        endif
        if method == 0
            Log name offset uncomp_size
        else
            if method == 8
                ComType deflate
            elif method == 1
                ComType unshrink
            elif method == 6
                ComType explode
            elif method == 9
                ComType deflate64
            elif method == 12
                ComType bzip2
            elif method == 14
                ComType lzmaefs
            elif method == 21
                ComType XMemDecompress
            elif method == 64
                ComType darksector
            elif method == 98
                ComType ppmd
            elif method == 99
                print "this script doesn't support AES encryption"
                cleanexit
            else
                print "unsupported compression method %method%"
                cleanexit
            endif
            CLog name offset comp_size uncomp_size
        endif
        if flag & 1
            encryption "" ""
        endif

        math offset += comp_size
        goto offset

    elif sign == 0x0806     # Archive extra data record
        get extra_len       long
        getdstring extra    extra_len

    elif sign == 0x0201     # Central directory structure
        get ver_made        short
        get ver_need        short
        get flag            short
        get method          short
        get modtime         short
        get moddate         short
        get crc             long
        get comp_size       long
        get uncomp_size     long
        get name_len        short
        get extra_len       short
        get comm_len        short
        get disknum         short
        get int_attr        short
        get ext_attr        long
        get rel_offset      long
        getdstring name     name_len
        getdstring extra    extra_len
        getdstring comment  comm_len

    elif sign == 0x0505     # Digital Signature
        get sign_len        long
        getdstring sign     sign_len

    elif sign == 0x0606     # Zip64 end of central directory record
        get dir_record      longlong
        get ver_made        short
        get ver_need        short
        get num_disk        long
        get num_disk2       long
        get tot_entries     longlong
        get tot_entries2    longlong
        get central_size    longlong
        get central_offset  longlong
        print "Error: zip64 extensible data sector not implemented, contact me"
        cleanexit

    elif sign == 0x0706     # Zip64 end of central directory locator
        get start_central   long
        get end_central     longlong
        get disks           long

    elif sign == 0x0605     # End of central directory record
        get disk_num        short
        get disk_start      short
        get central_entries short
        get central_entries short
        get central_size    long
        get central_offset  long
        get comm_len        short
        getdstring comment  comm_len

    elif sign == 0x0807     # Data Descriptor
        get crc             long
        get comp_size       long
        get uncomp_size     long

    elif sign == 0x3030     # disk spanning
        # nothing?

    else
        print "\nError: unknown ZIP signature %sign% at offset %offset%\n       if the other files have been extracted correctly it's all ok"
        cleanexit
    endif
    savepos offset
next

it gives an error at the end of the extraction but it's ok and extract the cfg file,
simple mod the cvars in the files you want (but the size must be the same or lower from the original so delete some empty space or text info)
and to reimport the modded files use this method

export:Open quickbms.exe, select the script.bms, select the zip file, select folder to export

reimport:  Delete first all the unmodded files from the extracted folder and keep only the modded files and folder/subfolder names, Open reimport, select script.bms,, select original zip file, select the modded folder with the custom/mods

and again it gives a error at the end of reimport but the modded zip works fine and have the modded files inside so the game start fine.
The only thing now is to figure out what is the correct files to mod because i try to bind a custom cvar in the config.360.cfg, controller.360.cfg and game360.cfg but it doesn't work.

[HEMI]

I would like to see some mods for Offline Mode only because that will help us getting the achievements much easier like how many kills you have or how many Awards and so on. If some one can mod the Stats it will be very helpful.

[curtdawg21]

i dont think there are binds in the gpd.... all of the stats are there though. i have them about 50% mapped out already

have you found the location for the rank yet? that seems to be the only one i cant find

[Buddah]

i have been at work all day so i have made no more progress, i will post back if i in fact find that location